new (from string)

    $a     = new Net::DNS::RR('host.example.com. 86400 A 192.0.2.1');
    $mx    = new Net::DNS::RR('example.com. 7200 MX 10 mailhost.example.com.');
    $cname = new Net::DNS::RR('www.example.com 300 IN CNAME host.example.com');
    $txt   = new Net::DNS::RR('txt.example.com 3600 HS TXT "text data"');

Returns an RR object of the appropriate type, or a "Net::DNS::RR" object if the type is not implemented. The attribute values are extracted from the string passed by the user. The syntax of the argument string follows the RFC1035 specification for zone files, and is compatible with the result returned by the string method.

The name and RR type are required; all other information is optional. If omitted, the TTL defaults to 0 and the RR class defaults to IN. Omitting the optional fields is useful for creating the empty RDATA sections required for certain dynamic update operations. See the "Net::DNS::Update" manual page for additional examples.

All names are interpreted as fully qualified domain names. The trailing dot (.) is optional.

new (from hash)

    $rr = new Net::DNS::RR(
            name    => 'host.example.com',
            ttl     => 86400,
            class   => 'IN',
            type    => 'A',
            address => '192.0.2.1'
            );
 
    $rr = new Net::DNS::RR(
            name    => 'txt.example.com',
            type    => 'TXT',
            txtdata => [ 'one', 'two' ]
            );

Returns an RR object of the appropriate type, or a "Net::DNS::RR" object if the type is not implemented. See the manual pages for each RR type to see what fields the type requires.

The "name" and "type" fields are required; all others are optional. If omitted, "ttl" defaults to 0 and "class" defaults to IN. Omitting the optional fields is useful for creating the empty RDATA sections required for certain dynamic update operations.

decode

    ( $rr, $next ) = decode Net::DNS::RR( \$data, $offset, @opaque );

Decodes a DNS resource record at the specified location within a DNS packet.

The argument list consists of a reference to the buffer containing the packet data and offset indicating where resource record begins. Remaining arguments, if any, are passed as opaque data to subordinate decoders.

Returns a "Net::DNS::RR" object and the offset of the next record in the packet.

An exception is raised if the data buffer contains insufficient or corrupt data.

Any remaining arguments are passed as opaque data to subordinate decoders and do not form part of the published interface.

encode

    $data = $rr->encode( $offset, @opaque );

Returns the "Net::DNS::RR" in binary format suitable for inclusion in a DNS packet buffer.

The offset indicates the intended location within the packet data where the "Net::DNS::RR" is to be stored.

Any remaining arguments are opaque data which are passed intact to subordinate encoders.

canonical

    $data = $rr->canonical;

Returns the "Net::DNS::RR" in canonical binary format suitable for DNSSEC signature validation.

The absence of the associative array argument signals to subordinate encoders that the canonical uncompressed lower case form of embedded domain names is to be used.

name

    $name = $rr->name;

Returns the owner name of the record.

type

    $type = $rr->type;

Returns the record type.

class

    $class = $rr->class;

Resource record class.

ttl

    $ttl = $rr->ttl;
    $ttl = $rr->ttl(3600);

Resource record time to live in seconds.

rdata

    $rr = new Net::DNS::RR( type => NULL, rdata => 'arbitrary' );

Resource record data section when viewed as opaque octets.

print

    $rr->print;

Prints the record to the standard output. Calls the string method to get the RR string representation.

string

    print $rr->string, "\n";

Returns a string representation of the RR using the zone file format described in RFC1035. All domain names are fully qualified with trailing dot. This differs from RR attribute methods, which omit the trailing dot.

rdstring

    $rdstring = $rr->rdstring;

Returns a string representation of the RR-specific data.

plain

    $plain = $rr->plain;

Returns a simplified single line representation of the RR using the zone file format defined in RFC1035. This facilitates interaction with programs like nsupdate which have simplified RR parsers.

token

    @token = $rr->token;

Returns a token list representation of the RR zone file string.

set_rrsort_func

    Net::DNS::RR::SRV->set_rrsort_func(
        'priority',
        sub {
            my ( $a, $b ) = ( $Net::DNS::a, $Net::DNS::b );
            $a->priority <=> $b->priority
            || $b->weight <=> $a->weight;
            }
        );
    Net::DNS::RR::SRV->set_rrsort_func(
        'default_sort',
        sub {
            my ( $a, $b ) = ( $Net::DNS::a, $Net::DNS::b );
            $a->priority <=> $b->priority
            || $b->weight <=> $a->weight;
            }
        );

set_rrsort_func needs to be called as a class method. The first argument is the attribute name on which the sorting will need to take place. If you specify "default_sort" then that is the sort algorithm that will be used in the case that rrsort() is called without an RR attribute as argument.

The second argument is a reference to a comparison function that uses the global variables $a and $b in the "from Net::DNS"(!!)package. During sorting, the variables $a and $b will contain references to objects of the class from which you called the set_prop_sort. In other words, you can rest assured that the above sorting function will only be applied to Net::DNS::RR::SRV objects.

The above example is the sorting function implemented in SRV.