Moose::Cookbook::Meta::Table_MetaclassTrait(3) User Contributed Perl Documentation Moose::Cookbook::Meta::Table_MetaclassTrait(3)

Moose::Cookbook::Meta::Table_MetaclassTrait - Adding a "table" attribute as a metaclass trait

version 2.2012

  # in lib/MyApp/Meta/Class/Trait/HasTable.pm
  package MyApp::Meta::Class::Trait::HasTable;
  use Moose::Role;
  Moose::Util::meta_class_alias('HasTable');
  has table => (
      is  => 'rw',
      isa => 'Str',
  );
  # in lib/MyApp/User.pm
  package MyApp::User;
  use Moose -traits => 'HasTable';
  __PACKAGE__->meta->table('User');

In this recipe, we'll create a class metaclass trait which has a "table" attribute. This trait is for classes associated with a DBMS table, as one might do for an ORM.

In this example, the table name is just a string, but in a real ORM the table might be an object describing the table.

This really is as simple as the recipe "SYNOPSIS" shows. The trick is getting your classes to use this metaclass, and providing some sort of sugar for declaring the table. This is covered in Moose::Cookbook::Extending::Debugging_BaseClassRole, which shows how to make a module like "Moose.pm" itself, with sugar like "has_table()".

Accessing this new "table" attribute is quite simple. Given a class named "MyApp::User", we could simply write the following:

  my $table = MyApp::User->meta->table;

As long as "MyApp::User" has arranged to apply the "MyApp::Meta::Class::Trait::HasTable" to its metaclass, this method call just works. If we want to be more careful, we can check that the class metaclass object has a "table" method:

  $table = MyApp::User->meta->table
      if MyApp::User->meta->can('table');

In theory, this is not entirely correct, since the metaclass might be getting its "table" method from a different trait. In practice, you are unlikely to encounter this sort of problem.

This recipe doesn't work when you paste it all into a single file. This is because the "use Moose -traits => 'HasTable';" line ends up being executed before the "table" attribute is defined.

When the two packages are separate files, this just works.

Moose::Cookbook::Meta::Labeled_AttributeTrait - Labels implemented via attribute traits =pod

This software is copyright (c) 2006 by Infinity Interactive, Inc.

This is free software; you can redistribute it and/or modify it under the same terms as the Perl 5 programming language system itself.

2019-11-22 perl v5.34.0